Sekiz farklı yazı stili(regex)

Alias-ımız: $_t(stil-ismi,[0-15],[0-15],text)

alias _t {
  if ($isid && $regex(+t,$1,/^(caps|color|bold|regular|underline|randomclr|reverse_(t|c))$/i)) {
    var %_t = $regml(+t,1),%_r = return,%_2 = $iif($2,$v1),%_3 = $iif($3,$v1),%_tx = $$2-
    if ($(,%_t) = caps) %_r $regsubex(%_tx,/(.(?<!\s))/g,$iif(2 \\ \n,$upper(\1),$lower(\1)))
    if ($(,%_t) = bold) %_r $regsubex(%_tx,/(.)/g,$chr(2)\1)
    if ($(,%_t) = reverse_c) %_r $regsubex(%_tx,/(.(?<!\s))/g,$chr(22)\1)
    if ($(,%_t) = underline) %_r $regsubex(%_tx,/(.(?<!\s))/g,$chr(31)\1)
    if ($(,%_t) = color) %_r $regsubex($$4-,/(.)/g,$iif(2 \\ \n,$+($chr(3),%_2,\1,$chr(3),%_3),\1))
    if ($(,%_t) = regular) %_r $regsubex(%_tx,/(?<=^|(?<=[.:;])|(?<=[.;:])\s)(.(?<![.;:]))/g,$chr(32) $upper(\1))
    if ($(,%_t) = randomclr) %_r $regsubex(%_tx,/(.)/g,$+($chr(3),$r($r(1,15),$r(1,\n)),\1))
    if ($(,%_t) = reverse_t) %_r $regsubex(%_tx,/(.)/g,$mid(%_tx,$mid(%_tx,\n,0),1))
  }
}

Alias-ın sağladığı yazı stilleri:

• Büyük/küçük yazı stili
• Kalın/ince yazı stili(ctrl+b)
• Reverse yazı stili(ctrl+r)
• Altı çizili yazı sitili(ctrl+u)
• Çift renkli yazı stili
• Düzenli cümle yazı stili
• Karışık renkli yazı stili
• Ters yazı stili

Kullanımlar:

• Büyük/küçük yazı stili için

İşlev: $_t(caps,text)
Örnek: //echo -: $_t(caps,bu bir denemedir.)

• Kalın/ince yazı stili için

İşlev: $_t(bold,text)
Örnek: //echo -: $_t(bold,bu bir denemedir.)

• Reverse yazı stili için

İşlev: $_t(reverse_c,text)
Örnek: //echo -: $_t(reverse_c,bu bir denemedir.)

• Altı çizili yazı stili için

İşlev: $_t(underline,text)
Örnek: //echo -: $_t(underline,bu bir denemedir.)

• Çift renkli yazı stili için

İşlev: $_t(color,[ilk-renk-kodu],[ikinci-renk-kodu],text)
Örnek: //echo -: $_t(color,2,4,bu bir denemedir.)

• Düzenli cümle yazı stili

İşlev: $_t(regular,text)
Örnek: //echo -: $_t(regular,bu bir denemedir.bu ikinci..birde bu;var..)

• Karışık renkli yazı stili için

İşlev: $_t(randomclr,text)
Örnek: //echo -: $_t(randomclr,bu bir denemedir.)

• Reverse yazı stili için

İşlev: $_t(reverse_c,text)
Örnek: //echo -: $_t(reverse_c,bu bir denemedir.)

• Ters yazı stili için

İşlev: $_t(reverse_t,text)
Örnek: //echo -: $_t(reverse_t,bu bir denemedir.)

Örnek resim:

İsteğe bağlı hazır kullanım(lar):

on *:input:*: {
  if ($regex($window($active).type,^(channel|query|chat)$) && $left($1,1) != /) {
    haltdef 
    ;kullanımlar
    ;say $_t(underline,$1-)
    ;say $_t(randomclr,$1-)
    ;say $_t(bold,$1-)
    ;say $_t(reverse_c,$1-)
    ;say $_t(reverse_t,$1-)
    ;say $_t(regular,$1-)
    ;say $_t(color,3,6,$1-)
    ;say $_t(caps,$1-)
    ;---
    ;kullanmak istediğiniz yazı stilinin başından ";" karakterini kaldırmanız yeterlidir.
    ;bu bir örnektir.
  }
}